gnome-photos/repos/testing-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-photos
   4 pkgver=43.0
   5 pkgrel=2
   6 epoch=1
   7 pkgdesc="Access, organize, and share your photos on GNOME"
   8 arch=(x86_64)
   9 url="https://wiki.gnome.org/Apps/Photos"
  10 license=(GPL)
  11 depends=(exempi gtk3 libexif librsvg babl gegl gsettings-desktop-schemas
  12          lcms2 tracker3-miners geocode-glib-2 libgdata libgexiv2 libraw
  13          gnome-online-accounts dleyna libdazzle libhandy libportal-gtk3)
  14 makedepends=(python yelp-tools git meson docbook-xsl)
  15 groups=(gnome)
  16 options=(debug)
  17 _commit=79de8be107a6c61c6f3a438601fc643c3d6946c2  # tags/43.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gnome-photos.git#commit=$_commit"
  19         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  20 sha256sums=('SKIP'
  21             'SKIP')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30
  31   git submodule init
  32   git submodule set-url subprojects/libgd "$srcdir/libgd"
  33   git -c protocol.file.allow=always submodule update
  34 }
  35
  36 build() {
  37   local meson_options=(
  38     -D manuals=true
  39   )
  40
  41   arch-meson $pkgname build "${meson_options[@]}"
  42   meson compile -C build
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "$pkgdir"
  47 }
  48
  49 # vim:set sw=2 sts=-1 et: