plasma-remotecontrollers/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 pkgname=plasma-remotecontrollers
   4 pkgver=5.26.2
   5 pkgrel=1
   6 pkgdesc='Translate various input device events into keyboard and pointer events'
   7 arch=(x86_64)
   8 url='https://plasma-bigscreen.org/'
   9 license=(GPL2)
  10 depends=(plasma-workspace)
  11 makedepends=(extra-cmake-modules plasma-wayland-protocols libcec)
  12 optdepends=('libcec: TV remotes support')
  13 source=(https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz{,.sig})
  14 sha256sums=('7a5f7da2153d1e425417bab4decccced6dd19ec0b757aae20b5c5e8e2c47f190'
  15             'SKIP')
  16 validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
  17               '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
  18               'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
  19               '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>
  20 options=(debug)
  21
  22 build() {
  23   cmake -B build -S $pkgname-$pkgver \
  24     -DBUILD_TESTING=OFF
  25   cmake --build build
  26 }
  27
  28 package() {
  29   DESTDIR="$pkgdir" cmake --install build
  30 }