qt6-speech/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt6-speech
   5 _qtver=6.4.0
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Qt Speech support'
  12 depends=(qt6-base)
  13 makedepends=(cmake ninja qt6-declarative qt6-multimedia speech-dispatcher flite)
  14 optdepends=('flite: flite TTS backend'
  15             'qt6-multimedia: flite TTS backend'
  16             'speech-dispatcher: speech-dispatcher TTS backend'
  17             'qt6-declarative: QML bindings')
  18 groups=(qt6)
  19 options=(debug)
  20 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  21 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  22 sha256sums=('873bc22096a8d01b1fcde148d5df3542dfa391ef76b8dde1cd2f6fbf87183df7')
  23
  24 build() {
  25   cmake -B build -S $_pkgfn -G Ninja \
  26     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  27   cmake --build build
  28 }
  29
  30 package() {
  31   DESTDIR="$pkgdir" cmake --install build
  32
  33   install -d "$pkgdir"/usr/share/licenses
  34   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  35 }