vte3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=vte3
   5 pkgname=(vte-common vte3 vte4 vte-docs)
   6 pkgver=0.72.1
   7 pkgrel=1
   8 pkgdesc="Virtual Terminal Emulator widget"
   9 url="https://wiki.gnome.org/Apps/Terminal/VTE"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 makedepends=(
  13   fribidi
  14   gi-docgen
  15   git
  16   gnutls
  17   gobject-introspection
  18   gperf
  19   gtk3
  20   gtk4
  21   meson
  22   pcre2
  23   systemd
  24   vala
  25 )
  26 options=(!lto)
  27 _commit=e86822b8b7013f96f3b3d2d86839395492cb1470  # tags/0.72.1^0
  28 source=("git+https://gitlab.gnome.org/GNOME/vte.git#commit=$_commit")
  29 sha256sums=('SKIP')
  30
  31 pkgver() {
  32   cd vte
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd vte
  38 }
  39
  40 build() {
  41   local meson_options=(
  42     -D b_lto=false
  43     -D docs=true
  44     -D gtk4=true
  45   )
  46
  47   arch-meson vte build "${meson_options[@]}"
  48   meson compile -C build
  49 }
  50
  51 check() {
  52   meson test -C build --print-errorlogs
  53 }
  54
  55 _pick() {
  56   local p="$1" f d; shift
  57   for f; do
  58     d="$srcdir/$p/${f#$pkgdir/}"
  59     mkdir -p "$(dirname "$d")"
  60     mv "$f" "$d"
  61     rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  62   done
  63 }
  64
  65 package_vte-common() {
  66   pkgdesc+=" (common files)"
  67   depends=(sh)
  68
  69   meson install -C build --destdir "$pkgdir"
  70
  71   cd "$pkgdir"
  72
  73   _pick gtk3 usr/bin/vte-2.91
  74   _pick gtk3 usr/include/vte-2.91
  75   _pick gtk3 usr/lib/libvte-2.91.so*
  76   _pick gtk3 usr/lib/pkgconfig/vte-2.91.pc
  77   _pick gtk3 usr/lib/girepository-1.0/Vte-2.91.typelib
  78   _pick gtk3 usr/share/gir-1.0/Vte-2.91.gir
  79   _pick gtk3 usr/share/glade
  80   _pick gtk3 usr/share/vala/vapi/vte-2.91.{deps,vapi}
  81
  82   _pick gtk4 usr/bin/vte-2.91-gtk4
  83   _pick gtk4 usr/include/vte-2.91-gtk4
  84   _pick gtk4 usr/lib/libvte-2.91-gtk4.so*
  85   _pick gtk4 usr/lib/pkgconfig/vte-2.91-gtk4.pc
  86   _pick gtk4 usr/lib/girepository-1.0/Vte-3.91.typelib
  87   _pick gtk4 usr/share/gir-1.0/Vte-3.91.gir
  88   _pick gtk4 usr/share/vala/vapi/vte-2.91-gtk4.{deps,vapi}
  89
  90   _pick docs usr/share/doc
  91 }
  92
  93
  94 package_vte3() {
  95   pkgdesc+=" (GTK3)"
  96   depends=(
  97     fribidi
  98     gnutls
  99     gtk3
 100     pcre2
 101     systemd
 102     vte-common
 103   )
 104   provides+=(libvte-2.91.so)
 105
 106   mv gtk3/* "$pkgdir"
 107 }
 108
 109 package_vte4() {
 110   pkgdesc+=" (GTK4)"
 111   depends=(
 112     fribidi
 113     gnutls
 114     gtk4
 115     pcre2
 116     systemd
 117     vte-common
 118   )
 119   provides+=(libvte-2.91-gtk4.so)
 120
 121   mv gtk4/* "$pkgdir"
 122 }
 123
 124 package_vte-docs() {
 125   pkgdesc+=" (documentation)"
 126
 127   mv docs/* "$pkgdir"
 128 }
 129
 130 # vim:set sw=2 sts=-1 et: