gnome-nibbles/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-nibbles
   5 pkgver=3.38.3
   6 pkgrel=1
   7 pkgdesc="Guide a worm around a maze"
   8 url="https://wiki.gnome.org/Apps/Nibbles"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(
  12   clutter-gtk
  13   gsound
  14   libgee
  15   libgnome-games-support
  16   librsvg
  17 )
  18 makedepends=(
  19   appstream-glib
  20   git
  21   gobject-introspection
  22   meson
  23   vala
  24   yelp-tools
  25 )
  26 groups=(gnome-extra)
  27 _commit=6eb6013344ab720275adadaeede5154e3d2afda2  # tags/3.38.3^0
  28 source=("git+https://gitlab.gnome.org/GNOME/gnome-nibbles.git#commit=$_commit")
  29 b2sums=('SKIP')
  30
  31 pkgver() {
  32   cd $pkgname
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd $pkgname
  38 }
  39
  40 build() {
  41   arch-meson $pkgname build
  42   meson compile -C build
  43 }
  44
  45 check() {
  46   meson test -C build --print-errorlogs
  47 }
  48
  49 package() {
  50   meson install -C build --destdir "$pkgdir"
  51 }
  52
  53 # vim:set sw=2 sts=-1 et: