wayland/trunk/PKGBUILD

   1 # Maintainer: Sébastien Luttringer <seblu@archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Joel Teichroeb <joel@teichroeb.net>
   4
   5 pkgbase=wayland
   6 pkgname=(wayland wayland-docs)
   7 pkgver=1.22.0
   8 pkgrel=1
   9 pkgdesc='A computer display server protocol'
  10 arch=('x86_64')
  11 url='https://wayland.freedesktop.org/'
  12 license=('MIT')
  13 depends=('glibc' 'libffi' 'expat' 'libxml2' 'default-cursors')
  14 makedepends=('meson' 'libxslt' 'doxygen' 'xmlto' 'graphviz' 'docbook-xsl')
  15 validpgpkeys=('C7223EBE4EF66513B892598911A30156E0E67611'  # Bryce Harrington
  16               'C0066D7DB8E9AC6844D728715E54498E697F11D7'  # Derek Foreman
  17               '34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48') # emersion <contact@emersion.fr>
  18 source=("https://gitlab.freedesktop.org/wayland/wayland/-/releases/$pkgver/downloads/wayland-$pkgver.tar.xz"{,.sig})
  19 sha256sums=('1540af1ea698a471c2d8e9d288332c7e0fd360c8f1d12936ebb7e7cbc2425842'
  20             'SKIP')
  21
  22 build() {
  23   arch-meson $pkgbase-$pkgver build
  24   meson compile -C build
  25 }
  26
  27 check() {
  28   meson test -C build --print-errorlogs
  29 }
  30
  31 package_wayland() {
  32   provides=(libwayland-{client,cursor,egl,server}.so)
  33
  34   meson install -C build --destdir "$pkgdir"
  35   mkdir -p docs/share
  36   mv "$pkgdir"/usr/share/{doc,man} docs/share
  37   install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  38 }
  39
  40 package_wayland-docs() {
  41   pkgdesc+=" (documentation)"
  42   depends=()
  43
  44   mv docs "$pkgdir/usr"
  45   install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: