gnome-notes/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-notes
   4 pkgver=40.1
   5 pkgrel=1
   6 pkgdesc="Write out notes, every detail matters"
   7 url="https://wiki.gnome.org/Apps/Notes"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(tracker3 glib2 gnome-online-accounts gtk3 json-glib
  11          evolution-data-server libhandy libxml2 curl util-linux-libs webkit2gtk)
  12 makedepends=(yelp-tools git meson)
  13 provides=("bijiben=$pkgver")
  14 conflicts=(bijiben)
  15 replaces=(bijiben)
  16 _commit=b5189e213b50cac50f5602945836dc4d85b17959  # tags/BIJIBEN_40_1^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-notes.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/^BIJIBEN_//;s/_/./g;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build -D update_mimedb=false
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   DESTDIR="$pkgdir" meson install -C build
  40 }