gnome-session/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-session
   4 pkgver=40.1.1
   5 pkgrel=1
   6 pkgdesc="The GNOME Session Handler"
   7 url="https://gitlab.gnome.org/GNOME/gnome-session"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(systemd dconf gsettings-desktop-schemas gtk3 gnome-desktop
  11          json-glib libgl libsm libxtst)
  12 makedepends=(mesa gtk-doc xtrans git python xmlto docbook-xsl meson)
  13 groups=(gnome)
  14 _commit=eace95defb1b285952452dfd2a790d39181d762e  # tags/40.1.1^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-session.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/\.beta/beta/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   DESTDIR="$pkgdir" meson install -C build
  38 }