irssi/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Dan McGee <dan@archlinux.org>
   4
   5 pkgname=irssi
   6 pkgver=1.2.3
   7 pkgrel=2
   8 pkgdesc='Modular text mode IRC client with Perl scripting'
   9 url='https://irssi.org/'
  10 arch=('x86_64')
  11 license=('GPL')
  12 depends=('glibc' 'glib2' 'openssl' 'libotr' 'perl' 'ncurses' 'libncursesw.so')
  13 optdepends=('perl-libwww: for the scriptassist script')
  14 replaces=('irssi-otr')
  15 backup=('etc/irssi.conf')
  16 source=(https://github.com/irssi/irssi/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc})
  17 sha512sums=('826b7bfd86a54647f2d344b6c461e1118b7382fb1637cf33c395af41a9a4ca5d8a794a415f0f0737178968cf2463bb46a0e7b7fd7014c968668b16183e0644bc'
  18             'SKIP')
  19 validpgpkeys=('7EE65E3082A5FB06AC7C368D00CCB587DDBEF0E1') # The Irssi project <staff@irssi.org>
  20
  21 build() {
  22   cd ${pkgname}-${pkgver}
  23   ./configure \
  24     --prefix=/usr \
  25     --sysconfdir=/etc \
  26     --with-proxy \
  27     --with-perl-lib=vendor \
  28     --with-otr
  29   make
  30 }
  31
  32 package() {
  33   cd ${pkgname}-${pkgver}
  34   make DESTDIR="${pkgdir}" install
  35 }
  36
  37 # vim: ts=2 sw=2 et: