libhandy/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=libhandy
   5 pkgver=1.4.0
   6 pkgrel=1
   7 pkgdesc="Library full of GTK+ widgets for mobile phones"
   8 url="https://gitlab.gnome.org/GNOME/libhandy"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2 gtk3)
  12 makedepends=(git gobject-introspection meson vala glade)
  13 checkdepends=(xorg-server-xvfb)
  14 provides=(libhandy-1.so)
  15 _commit=f8626427acebfa08b2b4ee1166d51e416d3d7407  # tags/1.4.0^0
  16 source=("git+https://gitlab.gnome.org/GNOME/libhandy.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 prepare() {
  20   cd libhandy
  21 }
  22
  23 pkgver() {
  24   cd libhandy
  25   git describe --tags | sed 's/^v//;s/-/+/g'
  26 }
  27
  28 build() {
  29   arch-meson libhandy build \
  30     -D gtk_doc=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   dbus-run-session xvfb-run -s '-nolisten local' \
  36     meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 et: