libsoup3/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libsoup3
   5 pkgver=3.0.3
   6 pkgrel=1
   7 pkgdesc="HTTP client/server library for GNOME"
   8 url="https://wiki.gnome.org/Projects/libsoup"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2 glib-networking sqlite krb5 libpsl brotli libnghttp2)
  12 makedepends=(gobject-introspection python vala git gtk-doc meson samba
  13              python-quart)
  14 checkdepends=(apache php-apache)
  15 optdepends=('samba: Windows Domain SSO')
  16 _commit=fbf69d004d1ef75bd93a10819378030b4c479bb9  # tags/3.0.3^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libsoup.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libsoup
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libsoup
  27 }
  28
  29 build() {
  30   arch-meson libsoup build \
  31     -D gtk_doc=true \
  32     -D autobahn=disabled \
  33     -D sysprof=disabled
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   depends+=(libg{lib,object,io}-2.0.so libgssapi_krb5.so libpsl.so
  43             libbrotlidec.so)
  44   provides+=(libsoup-3.0.so)
  45
  46   meson install -C build --destdir "$pkgdir"
  47 }
  48
  49 # vim:set sw=2 et: