lsof/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Angel Velasquez <angvp@archlinux.org>
   4 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   5 # Contributor: Aaron Griffin <aaron@archlinux.org>
   6 # Contributor: Jochem Kossen <j.kossen@home.nl>
   7 # Contributor: Hendrik Meyer <archlinux@t4cc0.re>
   8
   9 pkgname=lsof
  10 pkgver=4.94.0
  11 pkgrel=1
  12 pkgdesc='Lists open files for running Unix processes'
  13 url='https://github.com/lsof-org/lsof'
  14 arch=('x86_64')
  15 license=('custom')
  16 depends=('glibc' 'libtirpc')
  17 source=(https://github.com/lsof-org/lsof/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz
  18         license.txt)
  19 sha512sums=('852b12e621e1dbf71e5f7fd848a200339ca278fbe8c39dcd33f745d1aea4e61552c0f30a3f6469ad9d4b86a9163e677f8c95298159ebd647357734225aa06c0c'
  20             '3bdbc8f213e9bdba946636498d21486e2b79d8ae44a45b284b4dff8875e76f992ab0977e3ed510525a8f74203028acb6b15315fda963666012874be4ce4fdd93')
  21
  22 prepare() {
  23   cd lsof-${pkgver}
  24
  25   sed -i 's|/\* #define\tHASSECURITY\t1 \*/|#define\tHASSECURITY\t1|' dialects/linux/machine.h
  26   sed -i "s|.so ./version|.ds VN ${pkgver}|" -i Lsof.8
  27 }
  28
  29 build() {
  30   cd lsof-${pkgver}
  31   ./Configure -n linux
  32   make CC="cc ${CFLAGS} ${CPPFLAGS} ${LDFLAGS}"
  33 }
  34
  35 package() {
  36   cd lsof-${pkgver}
  37
  38   install -Dm 755 lsof -t "${pkgdir}"/usr/bin
  39   install -Dm 644 Lsof.8 "${pkgdir}"/usr/share/man/man8/lsof.8
  40   install -Dm 644 "${srcdir}"/license.txt \
  41        "${pkgdir}"/usr/share/licenses/lsof/LICENSE
  42 }
  43
  44 # vim: ts=2 sw=2 et: