opencl-clhpp/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2
   3 pkgname=opencl-clhpp
   4 pkgver=2.0.15
   5 pkgrel=1
   6 pkgdesc='OpenCL C++ header files'
   7 arch=('any')
   8 url='https://github.com/KhronosGroup/OpenCL-CLHPP'
   9 license=('custom')
  10 makedepends=('cmake' 'doxygen' 'graphviz')
  11 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/KhronosGroup/OpenCL-CLHPP/archive/v${pkgver}.tar.gz")
  12 sha256sums=('0175806508abc699586fc9a9387e01eb37bf812ca534e3b493ff3091ec2a9246')
  13 depends=('opencl-headers')
  14
  15 build() {
  16   cd "${srcdir}"/OpenCL-CLHPP*/
  17
  18   cmake -B build ./ \
  19     -DCMAKE_INSTALL_PREFIX=/usr \
  20     -DBUILD_DOCS=On \
  21     -DBUILD_EXAMPLES=Off \
  22     -DBUILD_TESTS=Off
  23   make -C build docs
  24 }
  25
  26 package() {
  27   cd "${srcdir}"/OpenCL-CLHPP*/
  28
  29   DESTDIR="$pkgdir" make -C build install
  30
  31   install -dm755 "${pkgdir}"/usr/share/doc/"${pkgname}"
  32   cp -r build/docs/html/* "${pkgdir}"/usr/share/doc/"${pkgname}"/
  33   install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
  34 }