vpnc/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Dave Reisner <dreisner@archlinux.org>
   3 # Contributor: Thomas Baechler <thomas@archlinux.org>
   4
   5 pkgname=vpnc
   6 _vpnc_commit=43780cecd7a61668002f73b6f8b9f9ba61af74ad
   7 _vpncscripts_commit=8fff06090ed193c4a7285e9a10b42e6679e8ecf3
   8 pkgver=0.5.3.r496.r153
   9 pkgrel=2
  10 epoch=1
  11 pkgdesc='VPN client for cisco3000 VPN Concentrators'
  12 url='https://github.com/streambinder/vpnc'
  13 arch=('x86_64')
  14 license=('GPL')
  15 depends=('libgcrypt' 'openssl' 'iproute2' 'which')
  16 optdepends=('perl: for pcf2vpnc')
  17 makedepends=('git')
  18 optdepends=('openresolv: Let vpnc manage resolv.conf')
  19 backup=('etc/vpnc/default.conf')
  20 source=("vpnc::git+https://github.com/streambinder/vpnc#commit=${_vpnc_commit}"
  21         "vpnc-scripts::git+https://gitlab.com/openconnect/vpnc-scripts.git#commit=${_vpncscripts_commit}"
  22         vpnc.conf
  23         vpnc@.service)
  24 sha512sums=('SKIP'
  25             'SKIP'
  26             'ac70712192c01ff638a9badc5cff7105bee5c4fed5d3a3b728e9597661952d156041c82fe1e544e2bab602d193d4105d3689c79c46d964623f6ce38dd89f0ea7'
  27             'cafcab676986c1a2e49441f01d61997f1c6b54bbb68661b9af007d4816f8e76eee6b7ac2dfab55b55965fa407e8331c663cf11aa79384c30b0c9049c1477b791')
  28
  29 pkgver() {
  30   cd ${pkgname}
  31   printf "%s.r%s.r%s" "$(grep '^VERSION' Makefile|sed 's|VERSION := ||')" \
  32     "$(git -C ../vpnc rev-list --count HEAD)" \
  33     "$(git -C ../vpnc-scripts rev-list --count HEAD)"
  34 }
  35
  36 prepare() {
  37   cd ${pkgname}
  38   # Build hybrid support
  39   sed 's|^#OPENSSL|OPENSSL|g' -i Makefile
  40   # fix resolvconf location for community/openresolv
  41   sed 's|/sbin/resolvconf|/usr/bin/resolvconf|g' -i ../vpnc-scripts/vpnc-script
  42   ln -sf ../../vpnc-scripts/vpnc-script src
  43   ln -sf ../../vpnc.conf src
  44 }
  45
  46 build() {
  47   make -C ${pkgname}
  48 }
  49
  50 check() {
  51   make -C ${pkgname} test
  52 }
  53
  54 package() {
  55   cd ${pkgname}
  56   make DESTDIR="${pkgdir}" PREFIX=/usr SBINDIR=/usr/bin install
  57   install -Dm 644 ../vpnc@.service -t "${pkgdir}/usr/lib/systemd/system"
  58   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  59   install -Dm 644 .github/README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  60   install -Dm 744 ../vpnc-scripts/vpnc-script -t "${pkgdir}/etc/vpnc"
  61 }
  62
  63 # vim: ts=2 sw=2 et: