xf86-video-openchrome/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Paul Mattal <paul@mattal.com>
   3 # Contributor: Juergen Hoetzel <juergen@hoetzel.info>
   4
   5 pkgname=xf86-video-openchrome
   6 _commit=15c868a # 7 digits # = 0.6.0 RC1
   7 pkgver=0.6.0.r754.g15c868a
   8 #pkgver=0.6.0
   9 pkgrel=1
  10 pkgdesc="X.Org Openchrome drivers"
  11 arch=(x86_64)
  12 license=('custom')
  13 url="https://www.freedesktop.org/wiki/Openchrome/"
  14 depends=('libdrm' 'libxvmc' 'systemd-libs')
  15 optdepends=('unichrome-dri')
  16 makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=25.2' 'systemd' 'libxv'
  17              'git')
  18 conflicts=('xorg-server<21.1.1' 'X-ABI-VIDEODRV_VERSION<25' 'X-ABI-VIDEODRV_VERSION>=26'
  19            'xf86-video-via' 'xf86-video-unichrome' 'openchrome')
  20 replaces=('openchrome' 'xf86-video-via')
  21 groups=('xorg-drivers')
  22 options=('!emptydirs')
  23 #source=(https://xorg.freedesktop.org/archive/individual/driver/${pkgname}-${pkgver}.tar.bz2{,.sig})
  24 #sha256sums=('da2975c6379358de52c1257710c67eb59139a7f0a1cd28d00cc64cc3e1c02f75'
  25 #            'SKIP')
  26 source=("git://anongit.freedesktop.org/openchrome/xf86-video-openchrome#commit=${_commit}")
  27 sha256sums=('SKIP')
  28 validpgpkeys=('CDA92E38A7A7A82237E9AB61C922784178BFFDB0') # "Kevin Brace <kevinbrace@gmx.com>"
  29
  30 pkgver() {
  31   cd $pkgname
  32   #git describe --long | sed 's/-/+/g'
  33 #  git describe --long | sed "s/openchrome-//;s/-/./g"
  34   git describe --long | sed 's/^xf86-video-openchrome-//;s/\([^-]*-g\)/r\1/;s/-/./g'
  35 #  git describe --long | sed "s/openchrome-//;s/0.5/0.5.200/;s/-/+/g"
  36 #  git describe --long | sed "s/openchrome-//;s/0.5/0.5.0/;s/-/+/g"
  37 }
  38
  39 prepare() {
  40   cd $pkgname
  41   NOCONFIGURE=1 ./autogen.sh
  42 }
  43
  44 build() {
  45   cd ${pkgname} #-${pkgver}
  46
  47   # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  48   # With them, module fail to load with undefined symbol.
  49   # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  50   export CFLAGS=${CFLAGS/-fno-plt}
  51   export CXXFLAGS=${CXXFLAGS/-fno-plt}
  52   export LDFLAGS=${LDFLAGS/,-z,now}
  53
  54   ./configure --prefix=/usr
  55   make
  56 }
  57
  58 check() {
  59   cd ${pkgname} #-${pkgver}
  60   make check
  61 }
  62
  63
  64 package() {
  65   cd ${pkgname} #-${pkgver}
  66   make DESTDIR="${pkgdir}" install
  67   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  68   install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  69 }