c-ares/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Dave Reisner <dreisner@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Jeff Mickey <jeff@archlinux.org>
   5 # Contributor: Alexander Fehr <pizzapunk gmail com>
   6
   7 pkgname=c-ares
   8 pkgver=1.19.0
   9 pkgrel=1
  10 pkgdesc="A C library for asynchronous DNS requests"
  11 arch=(x86_64)
  12 url="https://c-ares.haxx.se/"
  13 license=(MIT)
  14 depends=(glibc)
  15 makedepends=(cmake)
  16 provides=(libcares.so)
  17 source=(https://github.com/$pkgname/$pkgname/releases/download/${pkgname//-}-${pkgver//./_}/$pkgname-$pkgver.tar.gz{,.asc})
  18 sha512sums=('a7f5988bef393afec08a225be92f6eee54a3e67170fb26cbe00dcc5c5a457b27037bbcfeccc39fb855ed72f100196958d6cbbe251bf1ccfbdd353be18f098359'
  19             'SKIP')
  20 b2sums=('d77be535dfa852bf3d91258ddf06b3c63a40123883adb83a4e5652d4b1b16801ddefefad70d83a7d6d9aa81c9c81956fef42bc778d7380d6b398ccfc9f8b82dc'
  21         'SKIP')
  22 validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg <daniel@haxx.se>
  23
  24 build() {
  25   local cmake_options=(
  26     -B build
  27     -DCMAKE_INSTALL_PREFIX=/usr
  28     -DCMAKE_BUILD_TYPE=None
  29     -S $pkgname-$pkgver
  30     -Wno-dev
  31   )
  32   cmake "${cmake_options[@]}"
  33   cmake --build build --verbose
  34 }
  35
  36 check() {
  37   ctest --test-dir build --output-on-failure
  38 }
  39
  40 package() {
  41   DESTDIR="$pkgdir" cmake --install build
  42   install -vDm 644 $pkgname-$pkgver/LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
  43   install -vDm 644 $pkgname-$pkgver/{AUTHORS,CHANGES,{CONTRIBUTING,README}.md,RELEASE-NOTES} -t "$pkgdir/usr/share/doc/$pkgname/"
  44 }