ctags/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: John Proctor <jproctor@prium.net>
   4
   5 pkgname=ctags
   6 _commit=3af413544a0ed0a4c52200894cfd6391f06d2e94
   7 pkgver=6.0.0
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc='Generates an index file of language objects found in source files'
  11 url='https://ctags.io/'
  12 arch=('x86_64')
  13 license=('GPL')
  14 depends=('glibc' 'libxml2' 'jansson' 'libyaml' 'libseccomp' 'libseccomp.so'
  15          'pcre2')
  16 makedepends=('git' 'python-docutils')
  17 provides=('universal-ctags')
  18 source=("git+https://github.com/universal-ctags/ctags.git#commit=$_commit")
  19 sha512sums=('SKIP')
  20
  21 pkgver() {
  22   git -C ctags describe --tags --match 'v*' | sed 's/^p//;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  23 }
  24
  25 prepare() {
  26   cd ctags
  27   autoreconf -fiv
  28 }
  29
  30 build() {
  31   cd ctags
  32   ./configure \
  33     --prefix=/usr \
  34     --sysconfdir=/etc \
  35     --localstatedir=/var \
  36     --libexecdir=/usr/lib
  37   make
  38 }
  39
  40 check() {
  41   make -C ctags check
  42 }
  43
  44 package() {
  45   make -C ctags DESTDIR="${pkgdir}" install
  46 }
  47
  48 # vim:set sw=2 et: