doxygen/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Dan McGee <dan@archlinux.org>
   3
   4 pkgbase=doxygen
   5 pkgname=('doxygen' 'doxygen-docs')
   6 pkgver=1.9.6
   7 pkgrel=1
   8 pkgdesc='Documentation system for C++, C, Java, IDL and PHP'
   9 url='http://www.doxygen.nl'
  10 arch=('x86_64')
  11 license=('GPL')
  12 makedepends=('cmake' 'gcc-libs' 'flex' 'qt5-base' 'texlive-core' 'ghostscript'
  13              'texlive-latexextra' 'graphviz' 'python' 'git')
  14 source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/doxygen/doxygen/archive/Release_${pkgver//./_}.tar.gz)
  15 sha256sums=('2a3ee47f7276b759f74bac7614c05a1296a5b028d3f6a79a88e4c213db78e7dc')
  16 sha512sums=('687ffedad87ee908987967ef6675141bc9b2a55bf88d871d275aee6c35af9615c70c12f25401b1b368b32e92a3d0534177ec8781d8fb614137b98f4862445e37')
  17 b2sums=('6a51cb5bcc5892dce9220f9f64b3834d6204ecfe2adeeaf86b8230adcde180e4cae7c0a691ecf0cf181559ea2a4ce734619beaabfdb6903b80fbe6cdad083198')
  18
  19 prepare() {
  20   cd ${pkgbase}-Release_${pkgver//./_}
  21   # Install the man pages in the right place
  22   sed -i 's:DESTINATION man/man1:DESTINATION "${CMAKE_INSTALL_PREFIX}/share/man/man1":g' \
  23     doc/CMakeLists.txt
  24 }
  25
  26 build() {
  27   cd ${pkgbase}-Release_${pkgver//./_}
  28
  29   cmake -B build \
  30     -DCMAKE_INSTALL_PREFIX:PATH=/usr \
  31     -DDOC_INSTALL_DIR:PATH=share/doc/doxygen \
  32     -DPYTHON_EXECUTABLE:FILE=/usr/bin/python \
  33     -Dbuild_doc:BOOL=ON \
  34     -Dbuild_wizard:BOOL=ON
  35   make -C build
  36   export CAIRO_DEBUG_PDF=1 # https://github.com/doxygen/doxygen/issues/9319
  37   make -C build docs -j1
  38 }
  39
  40 check() {
  41   cd ${pkgbase}-Release_${pkgver//./_}
  42   make -C build tests
  43 }
  44
  45 package_doxygen() {
  46   pkgdesc='Documentation system for C++, C, Java, IDL and PHP'
  47   depends=('gcc-libs')
  48   optdepends=('graphviz: for caller/callee graph generation'
  49               'qt5-base: for doxywizard')
  50
  51   cd ${pkgbase}-Release_${pkgver//./_}
  52   make -C build DESTDIR="${pkgdir}" install
  53
  54   rm -rf "${pkgdir}/usr/share/doc"
  55 }
  56
  57 package_doxygen-docs() {
  58   pkgdesc='Developer documentation for doxygen'
  59
  60   cd ${pkgbase}-Release_${pkgver//./_}
  61   make -C build DESTDIR="${pkgdir}" install
  62
  63   rm -rf "${pkgdir}/usr/bin"
  64   rm -rf "${pkgdir}/usr/share/man"
  65 }
  66
  67 # vim: ts=2 sw=2 et: