gmime3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Ben <ben@benmazer.net>
   4
   5 pkgname=gmime3
   6 pkgver=3.2.13
   7 pkgrel=1
   8 pkgdesc="A C/C++ MIME creation and parser library with support for S/MIME, PGP, and Unix mbox spools"
   9 url="https://github.com/jstedfast/gmime"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(glib2 gpgme zlib libidn2)
  13 makedepends=(gobject-introspection gtk-doc git vala docbook-utils)
  14 provides=(libgmime-3.0.so)
  15 options=(debug)
  16 _commit=da1b041a2ce7e5e5c9d2c3e9499fe71b7a84d222  # tags/3.2.13^0
  17 source=("git+https://github.com/jstedfast/gmime#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd gmime
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd gmime
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd gmime
  32   ./configure \
  33     --prefix=/usr \
  34     --sysconfdir=/etc \
  35     --localstatedir=/var \
  36     --enable-gtk-doc \
  37     --enable-smime \
  38     --disable-static
  39   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  40   make
  41 }
  42
  43 check() {
  44   cd gmime
  45   make check
  46 }
  47
  48 package() {
  49   cd gmime
  50   make DESTDIR="$pkgdir" install
  51 }