gnote/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: uastasi <uastasi@archlinux.us>
   5
   6 pkgname=gnote
   7 pkgver=44.0
   8 pkgrel=1
   9 pkgdesc="A note taking application"
  10 url="https://wiki.gnome.org/Apps/Gnote"
  11 arch=(x86_64)
  12 license=(GPL3)
  13 depends=(
  14   gspell
  15   gtkmm3
  16   libsecret
  17   libxslt
  18 )
  19 makedepends=(
  20   git
  21   meson
  22   yelp-tools
  23 )
  24 _commit=22c42a15660df97cd499e771212837d3ece1c699  # tags/44.0^0
  25 source=("git+https://gitlab.gnome.org/GNOME/gnote.git#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd gnote
  30   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  31 }
  32
  33 prepare() {
  34   cd gnote
  35 }
  36
  37 build() {
  38   arch-meson gnote build
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build
  44 }
  45
  46 package() {
  47   meson install -C build --destdir "$pkgdir"
  48 }
  49
  50 # vim:set sw=2 sts=-1 et: