gupnp-dlna/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=gupnp-dlna
   5 pkgver=0.12.0
   6 pkgrel=2
   7 pkgdesc="Library to ease DLNA-related bits for applications using gupnp"
   8 url="https://wiki.gnome.org/Projects/GUPnP"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gst-plugins-base-libs)
  12 makedepends=(gobject-introspection gtk-doc vala meson git)
  13 options=(debug)
  14 _commit=cc09daae47ef0e030895edbeba58636c76f53b3d  # tags/gupnp-dlna-0.12.0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gupnp-dlna.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/^gupnp-dlna-//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build -D gtk_doc=true
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build
  34 }
  35
  36 package() {
  37   depends+=(libg{lib,object}-2.0.so)
  38   provides+=(libgupnp-dlna{,-gst}-2.0.so)
  39
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: