krita/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux,org>
   2
   3 pkgname=krita
   4 _pkgver=5.1.5
   5 pkgver=${_pkgver/-/}
   6 pkgrel=7
   7 pkgdesc='Edit and paint images'
   8 arch=(x86_64)
   9 url='https://krita.org'
  10 license=(GPL3)
  11 depends=(kitemviews kitemmodels ki18n kcompletion kguiaddons kcrash qt5-svg qt5-multimedia quazip
  12          gsl libraw exiv2 openexr fftw openjpeg2 opencolorio libwebp hicolor-icon-theme)
  13 makedepends=(extra-cmake-modules kdoctools boost eigen poppler-qt5 python-pyqt5 libheif
  14              qt5-tools sip kseexpr libmypaint libjxl xsimd)
  15 optdepends=('poppler-qt5: PDF filter' 'ffmpeg: to save animations'
  16             'python-pyqt5: for the Python plugins' 'libheif: HEIF filter'
  17             'kseexpr: SeExpr generator layer' 'kimageformats: PSD support' 'libmypaint: support for MyPaint brushes'
  18             'krita-plugin-gmic: GMic plugin' 'libjxl: JPEG-XL filter')
  19 source=(https://download.kde.org/stable/krita/$_pkgver/$pkgname-$_pkgver.tar.gz{,.sig}
  20         find-xsimd.patch
  21         https://invent.kde.org/graphics/krita/-/commit/e9184281.patch
  22         https://invent.kde.org/graphics/krita/-/commit/bbee5eff.patch)
  23 sha256sums=('1c775ebef0f799a9a6b74440c3d906ab913c27541b177ed621704de714e9a4d3'
  24             'SKIP'
  25             '622c9ffbbfef72dd024b391b879c79ae34da11d52b2f3488dfd8ee42bf7b453b'
  26             '3db041acee92d6e4238c47ad572142a930340858703f523baa32f129e6474060'
  27             '0f52ba825ce0432e55c1c673d8ebbd34f4353470a6c27bdc55beb2a5446f9a4a')
  28 validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD'  # Boudewijn Rempt <foundation@krita.org>
  29               'E9FB29E74ADEACC5E3035B8AB69EB4CF7468332F'  # Dmitry Kazakov (main key) <dimula73@gmail.com>
  30               '064182440C674D9F8D0F6F8B4DA79EDA231C852B') # Stichting Krita Foundation <foundation@krita.org>
  31
  32 prepare() {
  33   patch -d $pkgname-$_pkgver -p1 < find-xsimd.patch
  34   patch -d $pkgname-$_pkgver -p1 < e9184281.patch # Fix build with libheif 1.14.1
  35   patch -d $pkgname-$_pkgver -p1 < bbee5eff.patch # Fix crash when loading some TIFF files
  36 }
  37
  38 build() {
  39   cmake -B build -S $pkgname-$_pkgver \
  40     -DBUILD_KRITA_QT_DESIGNER_PLUGINS=ON
  41   cmake --build build
  42 }
  43
  44 package() {
  45   DESTDIR="$pkgdir" cmake --install build
  46 }