libodfgen/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Yue
   4
   5 pkgname=libodfgen
   6 pkgver=0.1.8
   7 pkgrel=2
   8 pkgdesc='Library for generating documents in Open Document Format'
   9 arch=('x86_64')
  10 url='https://sourceforge.net/p/libwpd/wiki/libodfgen/'
  11 license=('MPL')
  12 depends=('zlib' 'librevenge' 'libxml2')
  13 makedepends=('boost' 'libwpg' 'libetonyek' 'doxygen')
  14 options=('debug')
  15 source=(https://sourceforge.net/projects/libwpd/files/libodfgen/libodfgen-$pkgver/$pkgname-$pkgver.tar.xz)
  16 sha1sums=('9b36d313e64c6ce1026485d521fbdeff7f47594c')
  17 sha256sums=('55200027fd46623b9bdddd38d275e7452d1b0ff8aeddcad6f9ae6dc25f610625')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21   ./configure --prefix=/usr --disable-werror
  22   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  23   make
  24 }
  25
  26 check() {
  27   cd $pkgname-$pkgver
  28   make check
  29 }
  30
  31 package() {
  32   cd $pkgname-$pkgver
  33   make DESTDIR="$pkgdir" install
  34 }