snowball/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=snowball
   4 pkgname=(snowball libstemmer)
   5 pkgver=2.2.0
   6 pkgrel=2
   7 pkgdesc="String processing language for creating stemming algorithms"
   8 url="https://snowballstem.org/"
   9 arch=(x86_64)
  10 license=(BSD)
  11 makedepends=(git)
  12 options=(debug)
  13 _commit=48a67a2831005f49c48ec29a5837640e23e54e6b  # tags/v2.2.0^0
  14 source=("git+https://github.com/snowballstem/snowball#commit=$_commit"
  15         dynamiclib.diff)
  16 sha256sums=('SKIP'
  17             'c031da5a11bafa079df6c33b38b8795b65cf2c91cc6b452dcf2b10612288a3e6')
  18
  19 pkgver() {
  20   cd snowball
  21   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd snowball
  26   git apply -3 ../dynamiclib.diff
  27 }
  28
  29 build() {
  30   cd snowball
  31   make
  32 }
  33
  34 # No check - needs external test data
  35
  36 package_snowball() {
  37   depends=(libstemmer)
  38
  39   cd snowball
  40
  41   install -Dt "$pkgdir/usr/bin" snowball stemwords
  42
  43   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  44 }
  45
  46 package_libstemmer() {
  47   pkgdesc="Stemming library supporting several languages"
  48   depends=(glibc)
  49   provides=(libstemmer.so)
  50
  51   cd snowball
  52
  53   install -Dt "$pkgdir/usr/include" -m644 include/libstemmer.h
  54   install -Dm644 libstemmer.so.0 "$pkgdir/usr/lib/libstemmer.so.0.0.0"
  55   ln -s libstemmer.so.0.0.0 "$pkgdir/usr/lib/libstemmer.so.0"
  56   ln -s libstemmer.so.0 "$pkgdir/usr/lib/libstemmer.so"
  57
  58   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  59 }