snowball/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=snowball
   4 pkgname=(snowball libstemmer)
   5 pkgver=2.2.0
   6 pkgrel=2
   7 pkgdesc="String processing language for creating stemming algorithms"
   8 url="https://snowballstem.org/"
   9 arch=(x86_64)
  10 license=(BSD)
  11 makedepends=(git)
  12 _commit=48a67a2831005f49c48ec29a5837640e23e54e6b  # tags/v2.2.0^0
  13 source=("git+https://github.com/snowballstem/snowball#commit=$_commit"
  14         dynamiclib.diff)
  15 sha256sums=('SKIP'
  16             'c031da5a11bafa079df6c33b38b8795b65cf2c91cc6b452dcf2b10612288a3e6')
  17
  18 pkgver() {
  19   cd snowball
  20   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd snowball
  25   git apply -3 ../dynamiclib.diff
  26 }
  27
  28 build() {
  29   cd snowball
  30   make
  31 }
  32
  33 # No check - needs external test data
  34
  35 package_snowball() {
  36   depends=(libstemmer)
  37
  38   cd snowball
  39
  40   install -Dt "$pkgdir/usr/bin" snowball stemwords
  41
  42   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  43 }
  44
  45 package_libstemmer() {
  46   pkgdesc="Stemming library supporting several languages"
  47   depends=(glibc)
  48   provides=(libstemmer.so)
  49
  50   cd snowball
  51
  52   install -Dt "$pkgdir/usr/include" -m644 include/libstemmer.h
  53   install -Dm644 libstemmer.so.0 "$pkgdir/usr/lib/libstemmer.so.0.0.0"
  54   ln -s libstemmer.so.0.0.0 "$pkgdir/usr/lib/libstemmer.so.0"
  55   ln -s libstemmer.so.0 "$pkgdir/usr/lib/libstemmer.so"
  56
  57   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  58 }