yajl/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Dave Reisner <d@falconindy.com>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Thomas Dziedzic < gostrc at gmail >
   5 # Contributor: Andrej Gelenberg <andrej.gelenberg@udo.edu>
   6
   7 pkgname=yajl
   8 pkgver=2.1.0
   9 pkgrel=5
  10 pkgdesc='Yet Another JSON Library'
  11 arch=('x86_64')
  12 url='https://lloyd.github.com/yajl/'
  13 license=('ISC')
  14 depends=('glibc')
  15 makedepends=('cmake')
  16 provides=('libyajl.so')
  17 source=("$pkgname-$pkgver.tar.gz::https://github.com/lloyd/$pkgname/archive/$pkgver.tar.gz")
  18 sha512sums=('9e786d080803df80ec03a9c2f447501e6e8e433a6baf636824bc1d50ecf4f5f80d7dfb1d47958aeb0a30fe459bd0ef033d41bc6a79e1dc6e6b5eade930b19b02')
  19 b2sums=('755ee1d9f8c59b730393468722dae9148cd63443a0c91f0e1894f5998b699303920b8f0748541bd280d132ee1c9dedd40ebc2a7e020a8fe65beb186f25af5402')
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   export CFLAGS+=" -ffat-lto-objects"
  24   cmake -DCMAKE_INSTALL_PREFIX='/usr' \
  25         -DCMAKE_BUILD_TYPE='None' \
  26         -Wno-dev \
  27         -B build \
  28         -S .
  29   make VERBOSE=1 -C build
  30 }
  31
  32 check() {
  33   cd "$pkgname-$pkgver"
  34   make VERBOSE=1 -C build test
  35   make VERBOSE=1 -C build test-api
  36 }
  37
  38 package() {
  39   cd "$pkgname-$pkgver"
  40   make DESTDIR="$pkgdir" install -C build
  41   install -vDm 644 COPYING -t "$pkgdir/usr/share/licenses/${pkgname}"
  42   install -vDm 644 {ChangeLog,README,TODO} -t "$pkgdir/usr/share/doc/${pkgname}"
  43 }