bzr/trunk/PKGBUILD

   1 # Maintainer : Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Hugo Doria <hugo@archlinux.org>
   3
   4 pkgname=bzr
   5 pkgver=2.7.0
   6 pkgrel=3
   7 pkgdesc='A decentralized revision control system (bazaar)'
   8 arch=('x86_64')
   9 url='https://bazaar.canonical.com/'
  10 license=('GPL')
  11 depends=('python2')
  12 optdepends=('python2-paramiko: SFTP support')
  13 source=("https://launchpad.net/bzr/${pkgver%.*}/${pkgver}/+download/bzr-${pkgver}.tar.gz"{,.sig}
  14         'bzr-lazy-regex.patch')
  15 sha256sums=('0d451227b705a0dd21d8408353fe7e44d3a5069e6c4c26e5f146f1314b8fdab3'
  16             'SKIP'
  17             'b53c3dc8cba6f2c9758b61f0e9f40fc8452304e1fec15345e282dcd9d5657542')
  18 validpgpkeys=('84736900600FF95EF23513F52975A150DEF6218F') # Vincent Ladeuil
  19
  20 prepare() {
  21   cd bzr-${pkgver}
  22
  23   sed 's|man/man1|share/man/man1|' -i setup.py
  24   sed 's|/usr/bin/env python|/usr/bin/env python2|' -i bzrlib/{plugins/bash_completion/bashcomp.py,tests/ssl_certs/create_ssls.py,patiencediff.py,_patiencediff_py.py}
  25
  26   patch -Np0 -i ../bzr-lazy-regex.patch
  27 }
  28
  29 build() {
  30   cd bzr-${pkgver}
  31
  32   python2 setup.py build
  33 }
  34
  35 package() {
  36   cd bzr-${pkgver}
  37
  38   python2 setup.py install --prefix='/usr' --root="${pkgdir}" --optimize='1'
  39
  40   install -dm 755 "${pkgdir}"/usr/share/bash-completion/completions
  41   install -m 644 contrib/bash/bzr "${pkgdir}"/usr/share/bash-completion/completions/
  42 }
  43
  44 # vim: ts=2 sw=2 et: