gupnp-igd/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=gupnp-igd
   5 pkgver=1.2.0
   6 pkgrel=2
   7 pkgdesc="A library to handle UPnP IGD port mapping"
   8 url="https://wiki.gnome.org/Projects/GUPnP"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gupnp)
  12 makedepends=(gobject-introspection git gtk-doc meson)
  13 _commit=a0aafc79ac8e258f849cdb2924cb11ec9162d0c5  # tags/1.2.0-correct^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gupnp-igd.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-correct//;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build -D gtk_doc=true
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   depends+=(libg{lib,object,io}-2.0.so libg{ssdp,upnp}-1.2.so)
  37   provides+=(libgupnp-igd-1.0.so)
  38
  39   meson install -C build --destdir "$pkgdir"
  40 }
  41