pipewire/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgbase=pipewire
   6 pkgname=(pipewire alsa-card-profiles pipewire-docs pipewire-alsa pipewire-jack
   7          pipewire-pulse gst-plugin-pipewire pipewire-zeroconf pipewire-v4l2
   8          pipewire-x11-bell)
   9 _commit=f274e53d25ee8f483ac6fce9e516bb1830abe88b  # tags/0.3.56
  10 pkgver=0.3.56
  11 pkgrel=1
  12 epoch=1
  13 pkgdesc="Low-latency audio/video router and processor"
  14 url="https://pipewire.org"
  15 arch=(x86_64)
  16 license=(MIT)
  17 makedepends=(alsa-lib bluez-libs avahi git dbus doxygen graphviz
  18              gst-plugins-base libcanberra libfdk-aac libfreeaptx libldac
  19              libpulse libsndfile libusb libx11 libxfixes lilv meson ncurses
  20              python-docutils rtkit sbc sdl2 valgrind webrtc-audio-processing)
  21 checkdepends=(desktop-file-utils)
  22 options=(debug)
  23 source=(git+https://gitlab.freedesktop.org/pipewire/pipewire.git#commit=$_commit)
  24 sha256sums=('SKIP')
  25
  26 pkgver() {
  27   cd pipewire
  28   git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
  29 }
  30
  31 prepare() {
  32   cd pipewire
  33
  34   # remove export of LD_LIBRARY_PATH for pw-jack as it would add /usr/lib
  35   sed -i '/LD_LIBRARY_PATH/d' pipewire-jack/src/pw-jack.in
  36 }
  37
  38 build() {
  39   local meson_options=(
  40     -D bluez5-codec-lc3plus=disabled
  41     -D docs=enabled
  42     -D jack=disabled
  43     -D jack-devel=true
  44     -D libjack-path=/usr/lib
  45     -D libcamera=disabled
  46     -D udevrulesdir=/usr/lib/udev/rules.d
  47     -D roc=disabled
  48     -D session-managers=[]
  49   )
  50
  51   arch-meson pipewire build "${meson_options[@]}"
  52   meson compile -C build
  53 }
  54
  55 check() {
  56   meson test -C build --print-errorlogs
  57 }
  58
  59 _pick() {
  60   local p="$1" f d; shift
  61   for f; do
  62     d="$srcdir/$p/${f#$pkgdir/}"
  63     mkdir -p "$(dirname "$d")"
  64     mv "$f" "$d"
  65     rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  66   done
  67 }
  68
  69 _ver=${pkgver:0:3}
  70
  71 package_pipewire() {
  72   license+=(LGPL)  # libspa-alsa
  73   depends=(alsa-card-profiles libdbus-1.so libncursesw.so libsndfile.so
  74            libudev.so libusb-1.0.so libasound.so libsystemd.so libbluetooth.so
  75            libsbc.so libldacBT_enc.so libfreeaptx.so libfdk-aac.so liblilv-0.so
  76            libwebrtc_audio_processing.so)
  77   optdepends=('pipewire-docs: Documentation'
  78               'pipewire-session-manager: Session manager'
  79               'pipewire-alsa: ALSA configuration'
  80               'pipewire-jack: JACK support'
  81               'pipewire-pulse: PulseAudio replacement'
  82               'gst-plugin-pipewire: GStreamer plugin'
  83               'pipewire-zeroconf: Zeroconf support'
  84               'pipewire-v4l2: V4L2 interceptor'
  85               'pipewire-x11-bell: X11 bell'
  86               'realtime-privileges: realtime privileges with rt module'
  87               'rtkit: realtime privileges with rtkit module')
  88   provides=(libpipewire-$_ver.so)
  89   install=pipewire.install
  90
  91   meson install -C build --destdir "$pkgdir"
  92
  93   ( cd "$pkgdir"
  94
  95     _pick acp usr/lib/udev
  96     _pick acp usr/share/alsa-card-profile
  97
  98     _pick docs usr/share/doc
  99
 100     _pick jack usr/bin/pw-jack
 101     _pick jack usr/include/jack
 102     _pick jack usr/lib/libjack*
 103     _pick jack usr/lib/pkgconfig/jack.pc
 104     _pick jack usr/share/man/man1/pw-jack.1
 105     _pick jack usr/share/pipewire/jack.conf
 106
 107     _pick pulse usr/bin/pipewire-pulse
 108     _pick pulse usr/lib/pipewire-$_ver/libpipewire-module-protocol-pulse.so
 109     _pick pulse usr/lib/pipewire-$_ver/libpipewire-module-pulse-tunnel.so
 110     _pick pulse usr/lib/systemd/user/pipewire-pulse.*
 111
 112     _pick gst usr/lib/gstreamer-1.0
 113
 114     _pick zeroconf usr/lib/pipewire-$_ver/libpipewire-module-{raop,zeroconf}-discover.so
 115
 116     _pick v4l2 usr/bin/pw-v4l2 usr/lib/pipewire-$_ver/v4l2
 117
 118     _pick x11-bell usr/lib/pipewire-$_ver/libpipewire-module-x11-bell.so
 119
 120     mkdir -p etc/alsa/conf.d
 121     ln -st etc/alsa/conf.d /usr/share/alsa/alsa.conf.d/50-pipewire.conf
 122
 123     # directories for overrides
 124     mkdir -p etc/pipewire/{client-rt,client,minimal,pipewire,pipewire-pulse}.conf.d
 125   )
 126
 127   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 128 }
 129
 130 package_alsa-card-profiles() {
 131   pkgdesc+=" - ALSA card profiles"
 132   license=(LGPL)
 133
 134   mv acp/* "$pkgdir"
 135 }
 136
 137 package_pipewire-docs() {
 138   pkgdesc+=" - documentation"
 139
 140   mv docs/* "$pkgdir"
 141
 142   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 143 }
 144
 145 package_pipewire-alsa() {
 146   pkgdesc+=" - ALSA configuration"
 147   depends=(wireplumber)
 148   provides=(pulseaudio-alsa)
 149
 150   mkdir -p "$pkgdir/etc/alsa/conf.d"
 151   ln -st "$pkgdir/etc/alsa/conf.d" \
 152     /usr/share/alsa/alsa.conf.d/99-pipewire-default.conf
 153
 154   install -Dm644 /dev/null \
 155     "$pkgdir/usr/share/pipewire/media-session.d/with-alsa"
 156
 157   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 158 }
 159
 160 package_pipewire-jack() {
 161   pkgdesc+=" - JACK support"
 162   license+=(GPL2)  # libjackserver
 163   depends=(wireplumber libpipewire-$_ver.so sh)
 164   optdepends=('jack-example-tools: for official JACK example-clients and tools')
 165   conflicts=(jack jack2)
 166   provides=(jack libjack.so libjackserver.so libjacknet.so)
 167
 168   mv jack/* "$pkgdir"
 169
 170   install -Dm644 /dev/null \
 171     "$pkgdir/usr/share/pipewire/media-session.d/with-jack"
 172
 173   # directories for overrides
 174   mkdir -p "$pkgdir/etc/pipewire/jack.conf.d"
 175
 176   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 177 }
 178
 179 package_pipewire-pulse() {
 180   pkgdesc+=" - PulseAudio replacement"
 181   depends=(wireplumber libpipewire-$_ver.so libpulse.so
 182            libavahi-{client,common}.so)
 183   provides=(pulseaudio pulseaudio-bluetooth)
 184   conflicts=(pulseaudio pulseaudio-bluetooth)
 185   install=pipewire-pulse.install
 186
 187   mv pulse/* "$pkgdir"
 188
 189   install -Dm644 /dev/null \
 190     "$pkgdir/usr/share/pipewire/media-session.d/with-pulseaudio"
 191
 192   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 193 }
 194
 195 package_gst-plugin-pipewire() {
 196   pkgdesc="Multimedia graph framework - pipewire plugin"
 197   depends=(pipewire-session-manager libpipewire-$_ver.so gst-plugins-base-libs)
 198
 199   mv gst/* "$pkgdir"
 200
 201   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 202 }
 203
 204 package_pipewire-zeroconf() {
 205   pkgdesc+=" - Zeroconf support"
 206   depends=(pipewire libpipewire-$_ver.so libavahi-{client,common}.so)
 207
 208   mv zeroconf/* "$pkgdir"
 209
 210   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 211 }
 212
 213 package_pipewire-v4l2() {
 214   pkgdesc+=" - V4L2 interceptor"
 215   depends=(pipewire-session-manager libpipewire-$_ver.so sh)
 216
 217   mv v4l2/* "$pkgdir"
 218
 219   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 220 }
 221
 222
 223 package_pipewire-x11-bell() {
 224   pkgdesc+=" - X11 bell"
 225   depends=(pipewire libpipewire-$_ver.so libx11 libxfixes libcanberra.so)
 226
 227   mv x11-bell/* "$pkgdir"
 228
 229   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
 230 }
 231 # vim:set sw=2 et: