qt6-quick3dphysics/repos/kde-unstable-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt6-quick3dphysics
   5 _qtver=6.4.0-beta2
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Physics engine integration for Qt Quick 3D'
  12 depends=(qt6-quick3d)
  13 makedepends=(cmake ninja qt6-shadertools)
  14 groups=(qt6)
  15 options=(debug)
  16 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  17 source=(https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  18 sha256sums=('c16d5d45b61a1d429a0864ef0f8dacf3970620900b77ea7f8151f0042a67c9f5')
  19
  20 build() {
  21   cmake -B build -S $_pkgfn -G Ninja \
  22     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  23   cmake --build build
  24 }
  25
  26 package() {
  27   DESTDIR="$pkgdir" cmake --install build
  28
  29   install -d "$pkgdir"/usr/share/licenses
  30   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  31 }