tracker3-miners/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=tracker3-miners
   4 pkgver=3.3.1
   5 pkgrel=1
   6 pkgdesc="Collection of data extractors for Tracker/Nepomuk"
   7 url="https://wiki.gnome.org/Projects/Tracker"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(tracker3 gst-plugins-base-libs exempi libexif libcue libgrss libgsf
  11          libgxps libiptcdata libosinfo poppler-glib totem-plparser giflib
  12          libgexiv2 gupnp-dlna upower libseccomp libnm)
  13 makedepends=(git meson vala asciidoc)
  14 checkdepends=(python-gobject python-tappy gst-plugins-good gst-plugins-base
  15               gst-libav)
  16 groups=(gnome)
  17 options=(debug)
  18 _commit=58f131bcf2aac9d485cce850eca5aaa72d40468a  # tags/3.3.1^0
  19 source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd tracker-miners
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd tracker-miners
  29 }
  30
  31 build() {
  32   arch-meson tracker-miners build -D tests_tap_protocol=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
  38   dbus-run-session meson test -C build --print-errorlogs -t 3 || :
  39 }
  40
  41 package() {
  42   depends+=(libtracker-sparql-3.0.so)
  43
  44   meson install -C build --destdir "$pkgdir"
  45 }
  46
  47 # vim:set sw=2 et: