bubblewrap/trunk/PKGBUILD

   1 # Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2
   3 pkgbase=bubblewrap
   4 pkgname=(bubblewrap bubblewrap-suid)
   5 pkgver=0.6.2
   6 pkgrel=1
   7 pkgdesc='Unprivileged sandboxing tool'
   8 url='https://github.com/projectatomic/bubblewrap'
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(glibc libcap)
  12 makedepends=(libxslt docbook-xsl git meson bash-completion)
  13 options=(debug)
  14 _commit=c54bbc6d7b78e7a45016efe0c4ac8af9d209aa20  # tags/v0.6.2^0
  15 source=("git+$url#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgbase
  20   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgbase
  25 }
  26
  27 build() {
  28   arch-meson $pkgbase build -D selinux=disabled
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package_bubblewrap() {
  37   meson install -C build --destdir "$pkgdir"
  38 }
  39
  40 package_bubblewrap-suid() {
  41   pkgdesc+=" (setuid variant)"
  42   provides=("bubblewrap=$pkgver-$pkgrel")
  43   conflicts=(bubblewrap)
  44
  45   meson install -C build --destdir "$pkgdir"
  46   chmod u+s "$pkgdir/usr/bin/bwrap"
  47 }