f2fs-tools/trunk/PKGBUILD

   1 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   2 # Contributor: Christian Hesse <mail@eworm.de>
   3
   4 pkgname=f2fs-tools
   5 _tag='64f2596142800c215cb40a658ebd5793ed37c936' # git rev-parse v${pkgver}
   6 pkgver=1.15.0
   7 pkgrel=1
   8 pkgdesc='Tools for Flash-Friendly File System (F2FS)'
   9 arch=('x86_64')
  10 url='https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git/about/'
  11 provides=('libf2fs.so' 'bf2fs_format.so')
  12 depends=('util-linux')
  13 makedepends=('git')
  14 license=('GPL')
  15 validpgpkeys=('D3452A79D8C2B4EAC656F4224014A87E824850D2') # Jaegeuk Kim <jaegeuk@kernel.org>
  16 source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git#tag=${_tag}")
  17 sha256sums=('SKIP')
  18
  19 prepare() {
  20         cd "${pkgname}"
  21
  22         autoreconf -fi
  23 }
  24
  25 build() {
  26         cd "${pkgname}"
  27
  28         ./configure \
  29                 --prefix=/usr \
  30                 --sbindir=/usr/bin
  31         make
  32 }
  33
  34 package() {
  35         cd "${pkgname}"
  36
  37         make DESTDIR="${pkgdir}/" sbindir=/usr/bin install
  38
  39         # /usr/bin/sg_write_buffer is provided in sg3_utils
  40         rm "${pkgdir}"/usr/bin/sg_write_buffer
  41 }