fprintd/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Nikolay Rysev <mad.f3ka@gmail.com>
   3
   4 pkgname=fprintd
   5 pkgver=1.94.2
   6 pkgrel=1
   7 pkgdesc="D-Bus service to access fingerprint readers"
   8 url="https://fprint.freedesktop.org/"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(glib2 libfprint polkit dbus dbus-glib systemd)
  12 makedepends=(gtk-doc git meson pam_wrapper python-cairo python-dbus
  13              python-dbusmock)
  14 groups=(fprint)
  15 options=(debug)
  16 _commit=0d2e2a6742cbec847aa756da25afd4b73d9ec53f  # tags/v1.94.2^0
  17 source=("git+https://gitlab.freedesktop.org/libfprint/fprintd.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd fprintd
  22   git describe --tags | sed 's/^v//;s/^V_//;s/_/./g;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd fprintd
  27 }
  28
  29 build() {
  30   arch-meson fprintd build \
  31     -D pam_modules_dir=/usr/lib/security \
  32     -D gtk_doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   depends+=(libfprint-2.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44 }