gdk-pixbuf2/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gdk-pixbuf2
   5 pkgname=(gdk-pixbuf2 gdk-pixbuf2-docs)
   6 pkgver=2.42.8
   7 pkgrel=1
   8 pkgdesc="An image loading library"
   9 url="https://wiki.gnome.org/Projects/GdkPixbuf"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 libpng libtiff libjpeg shared-mime-info)
  13 makedepends=(gobject-introspection git meson gi-docgen docbook-xsl)
  14 optdepends=(
  15   "libwmf: Load .wmf and .apm"
  16   "libopenraw: Load .dng, .cr2, .crw, .nef, .orf, .pef, .arw, .erf, .mrw, and .raf"
  17   "libavif: Load .avif"
  18   "libheif: Load .heif, .heic, and .avif"
  19   "libjxl: Load .jxl"
  20   "librsvg: Load .svg, .svgz, and .svg.gz"
  21   "webp-pixbuf-loader: Load .webp"
  22 )
  23 options=(debug)
  24 _commit=bca00032ad68d0b0aa2c1f7558db931e52bd9cd2  # tags/2.42.8^0
  25 source=(
  26   "git+https://gitlab.gnome.org/GNOME/gdk-pixbuf.git#commit=$_commit"
  27   gdk-pixbuf-query-loaders.hook
  28 )
  29 sha256sums=('SKIP'
  30             '9fb71d95e6a212779eb0f88dde5a3cee0df7f4d9183f8f9ce286f8cdc14428f0')
  31
  32 pkgver() {
  33   cd gdk-pixbuf
  34   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  35 }
  36
  37 prepare() {
  38   cd gdk-pixbuf
  39 }
  40
  41 build() {
  42   arch-meson gdk-pixbuf build \
  43     -D builtin_loaders=all \
  44     -D gtk_doc=true \
  45     -D installed_tests=false
  46   meson compile -C build
  47 }
  48
  49 check() {
  50   meson test -C build --print-errorlogs
  51 }
  52
  53 package_gdk-pixbuf2() {
  54   provides=(libgdk_pixbuf-2.0.so)
  55   install=gdk-pixbuf2.install
  56
  57   meson install -C build --destdir "$pkgdir"
  58
  59   mkdir -p doc/usr/share
  60   mv {"$pkgdir",doc}/usr/share/doc
  61
  62   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  63 }
  64
  65 package_gdk-pixbuf2-docs() {
  66   pkgdesc+=" (documentation)"
  67   depends=()
  68
  69   mv doc/* "$pkgdir"
  70 }
  71
  72 # vim:set sw=2 et: