gnome-themes-extra/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2
   3 pkgname=gnome-themes-extra
   4 pkgver=3.28+r6+g45b1d457
   5 pkgrel=1
   6 pkgdesc="Extra Themes for GNOME Applications"
   7 url="https://gitlab.gnome.org/GNOME/gnome-themes-extra"
   8 arch=(x86_64)
   9 license=(LGPL2.1)
  10 depends=(cantarell-fonts)
  11 makedepends=(intltool gtk2 gtk3 git)
  12 optdepends=('gtk-engines: HighContrast GTK2 theme')
  13 provides=("gnome-themes-standard=$pkgver")
  14 conflicts=(gnome-themes-standard)
  15 replaces=('gnome-themes-standard<3.27.92')
  16 options=('!emptydirs')
  17 _commit=45b1d457c63b1c7f6c8dcb7fe29b23ec7cd63a14  # master
  18 source=("git+https://gitlab.gnome.org/GNOME/gnome-themes-extra.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28   NOCONFIGURE=1 ./autogen.sh
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 package() {
  39   cd $pkgname
  40   make DESTDIR="$pkgdir" install
  41 }
  42
  43 # vim:set ts=2 sw=2 et: