gtksourceview5/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4
   5 pkgbase=gtksourceview5
   6 pkgname=(gtksourceview5 gtksourceview5-docs)
   7 pkgver=5.4.2
   8 pkgrel=1
   9 pkgdesc="A text widget adding syntax highlighting and more to GNOME"
  10 url="https://wiki.gnome.org/Projects/GtkSourceView"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(gtk4 libxml2 pcre2)
  14 makedepends=(gobject-introspection vala gi-docgen git meson)
  15 checkdepends=(xorg-server-xvfb)
  16 options=(debug)
  17 _commit=ec0b434c4ebea7e9c1920013af2a911c4b28a66a  # tags/5.4.2^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd gtksourceview
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd gtksourceview
  28 }
  29
  30 build() {
  31   arch-meson gtksourceview build -D gtk_doc=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   dbus-run-session xvfb-run -s '-nolisten local' \
  37     meson test -C build --print-errorlogs
  38 }
  39
  40 package_gtksourceview5() {
  41   provides=(libgtksourceview-${pkgver%%.*}.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44
  45   mkdir -p doc/usr/share
  46   mv {"$pkgdir",doc}/usr/share/doc
  47 }
  48
  49 package_gtksourceview5-docs() {
  50   pkgdesc+=" (documentation)"
  51   depends=()
  52
  53   mv doc/* "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 et: