json-glib/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=json-glib
   5 pkgname=(json-glib json-glib-docs)
   6 pkgver=1.6.6
   7 pkgrel=2
   8 pkgdesc="JSON library built on GLib"
   9 url="https://wiki.gnome.org/Projects/JsonGlib"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(glib2)
  13 makedepends=(gobject-introspection git meson gi-docgen docbook-xsl)
  14 options=(debug)
  15 _commit=3cf2b53667a73376c852e08dcadd197a5f8325b9  # tags/1.6.6^0
  16 source=("git+https://gitlab.gnome.org/GNOME/json-glib.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd json-glib
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd json-glib
  26 }
  27
  28 build() {
  29   arch-meson json-glib build -D man=true
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package_json-glib() {
  38   depends+=(libg{lib,object,io}-2.0.so)
  39   provides+=(libjson-glib-1.0.so)
  40
  41   meson install -C build --destdir "$pkgdir"
  42
  43   mkdir -p doc/usr/share
  44   mv {"$pkgdir",doc}/usr/share/doc
  45
  46   rm -r "$pkgdir"/usr/{lib,share}/installed-tests
  47 }
  48
  49 package_json-glib-docs() {
  50   pkgdesc+=" (documentation)"
  51   depends=()
  52
  53   mv doc/* "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 et: