libdazzle/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libdazzle
   5 pkgver=3.44.0
   6 pkgrel=1
   7 pkgdesc="A library to delight your users with fancy features"
   8 url="https://gitlab.gnome.org/GNOME/libdazzle"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gtk3)
  12 makedepends=(git meson vala gobject-introspection gtk-doc)
  13 checkdepends=(xorg-server-xvfb)
  14 provides=(libdazzle-1.0.so)
  15 options=(debug)
  16 _commit=03933375700e8c5463ae02a54c31dbc29c6f6804  # tags/3.44.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libdazzle.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 build() {
  26   arch-meson $pkgname build -D enable_gtk_doc=true
  27   meson compile -C build
  28 }
  29
  30 check() {
  31   dbus-run-session xvfb-run -s '-nolisten local' \
  32     meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   meson install -C build --destdir "$pkgdir"
  37 }