libfido2/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Karol Babioch <karol@babioch.de>
   3
   4 pkgname=libfido2
   5 pkgver=1.11.0
   6 pkgrel=1
   7 pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
   8 url='https://developers.yubico.com/libfido2/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so' 'zlib')
  12 makedepends=('cmake' 'systemd')
  13 provides=('libfido2.so')
  14 source=("https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz"{,.sig})
  15 sha512sums=('d9644453d67b84ec8385dfb63796adb3eae2d7f7cb47fbb1bcf9ca7f5cce400623738cc3317d629c2f0af630424cb2788217f8c7f20d1b52b7369c729052d572'
  16             'SKIP')
  17 b2sums=('ac123145f22260922e1d83653ba5781c5f41b410760f2c26b7cab7cb0871079aed66a8d9747393843738e4c2ed7ba8ba0292075516ef0354fd4328df967b7a6d'
  18         'SKIP')
  19 validpgpkeys=(
  20   'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro@yubico.com>
  21   '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail@yubico.com>
  22   '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas@yubico.com>
  23 )
  24
  25 build() {
  26   cd ${pkgname}-${pkgver}
  27   # do not use bundled udev rules superseded by systemd
  28   cmake -B build \
  29     -DCMAKE_INSTALL_PREFIX=/usr \
  30     -DCMAKE_INSTALL_LIBDIR=lib \
  31     -DCMAKE_BUILD_TYPE=Release \
  32     -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
  33     -Wno-dev \
  34     -S .
  35   make -C build VERBOSE=1
  36 }
  37
  38 package() {
  39   cd ${pkgname}-${pkgver}
  40   make -C build DESTDIR="${pkgdir}" install
  41   install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  42   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  43 }
  44
  45 # vim: ts=2 sw=2 et: