libgweather-4/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=libgweather-4
   5 pkgname=(libgweather-4 libgweather-4-docs)
   6 pkgver=4.0.0
   7 pkgrel=1
   8 pkgdesc="Location and timezone database and weather-lookup library"
   9 url="https://wiki.gnome.org/Projects/LibGWeather"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(libsoup geocode-glib dconf)
  13 makedepends=(gobject-introspection vala git gi-docgen meson python-gobject)
  14 checkdepends=(python-pylint)
  15 options=(debug)
  16 _commit=6ac9872a5a06863f6c84f6ac836cede78b401691  # tags/4.0.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libgweather.git#commit=$_commit"
  18         disable-metar-test.diff)
  19 sha256sums=('SKIP'
  20             'c11eb9ad69f8354e5baeef5581038ef0cd5ce2f032dd48f3df29e34fc900dd5a')
  21
  22 pkgver() {
  23   cd libgweather
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd libgweather
  29
  30   # Disable metar test, depends on unstable online service
  31   git apply -3 ../disable-metar-test.diff
  32 }
  33
  34 build() {
  35   arch-meson libgweather build -D gtk_doc=true
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package_libgweather-4() {
  44   provides=(libgweather-4.so)
  45
  46   meson install -C build --destdir "$pkgdir"
  47
  48   mkdir -p doc/usr/share
  49   mv {"$pkgdir",doc}/usr/share/doc
  50 }
  51
  52 package_libgweather-4-docs() {
  53   pkgdesc+=" (documentation)"
  54   depends=()
  55
  56   mv doc/* "$pkgdir"
  57 }
  58
  59 # vim:set sw=2 et: