live-media/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Gilles CHAUVIN <gcnweb@gmail.com>
   4
   5 pkgname=live-media
   6 pkgver=2022.04.26
   7 pkgrel=1
   8 pkgdesc='Set of C++ libraries for multimedia streaming'
   9 url='http://live555.com/liveMedia'
  10 arch=('x86_64')
  11 license=('LGPL')
  12 depends=('gcc-libs' 'openssl')
  13 options=('staticlibs')
  14 source=(https://download.videolan.org/contrib/live555/live.${pkgver}.tar.gz)
  15 sha256sums=('24fd24d53da1ac8f8282173039e99c9952186c18404b1fc3b1d4c0e9f49414e7')
  16 sha512sums=('0226a451129df1d47d10bc96ef2a9ab8ffb0116fd0daac8b16a1dd57b319b9058b587955a01bc4a939c3f64659915815fe182c8c7b02cb286313ff132dcbe144')
  17
  18 build() {
  19   cd live
  20   export CFLAGS+=" -ffat-lto-objects"
  21   export CXXFLAGS+=" -ffat-lto-objects"
  22   sed -E 's|(-DSOCKLEN_T=socklen_t)|\1 -fPIC -DRTSPCLIENT_SYNCHRONOUS_INTERFACE=1|g' -i config.linux
  23   ./genMakefiles linux
  24   make
  25 }
  26
  27 package() {
  28   cd live
  29   for dir in BasicUsageEnvironment groupsock liveMedia UsageEnvironment; do
  30     install -Dm 644 ${dir}/*.a -t "${pkgdir}/usr/lib"
  31     install -Dm 644 ${dir}/include/*.h* -t "${pkgdir}/usr/include/${dir}"
  32   done
  33   find testProgs -type f -perm 755 -print0|xargs -0 -I '{}' install -Dm 755 '{}' -t "${pkgdir}/usr/bin"
  34 }
  35
  36 # vim: ts=2 sw=2 et: