mobile-broadband-provider-info/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=mobile-broadband-provider-info
   5 pkgver=20220725
   6 pkgrel=1
   7 pkgdesc="Network Management daemon"
   8 url="https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info"
   9 arch=(any)
  10 license=(custom)
  11 makedepends=(git libxslt)
  12 _commit=fe19892a8168bf19d81e3bc4ee319bf7f9f058f5  # tags/20220725^0
  13 source=("git+https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info.git#commit=$_commit")
  14 sha256sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  19 }
  20
  21 prepare() {
  22   cd $pkgname
  23   NOCONFIGURE=1 ./autogen.sh
  24 }
  25
  26 check() {
  27   cd $pkgname
  28   make check
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  41 }