pcre2/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Mateusz 'mrlemux' Lemusisk mrlemux at gmail dotcom
   3 # Based on the pcre package by Sébastien "Seblu" Luttringer
   4 # Contributor: Allan McRae <allan@archlinux.org>
   5 # Contributor: Eric Belanger <eric@archlinux.org>
   6 # Contributor: John Proctor <jproctor@prium.net>
   7
   8 pkgname=pcre2
   9 pkgver=10.40
  10 pkgrel=1
  11 pkgdesc='A library that implements Perl 5-style regular expressions. 2nd version'
  12 arch=('x86_64')
  13 url='https://www.pcre.org/'
  14 license=('BSD')
  15 depends=('gcc-libs' 'readline' 'zlib' 'bzip2' 'bash')
  16 source=("https://github.com/PhilipHazel/pcre2/releases/download/$pkgname-$pkgver/$pkgname-$pkgver.tar.bz2"{,.sig})
  17 sha512sums=('00e7b48a6554b9127cb6fe24c5cacf72783416a9754ec88f62f73c52f46ed72c86c1869e62c91a31b2ff2cbafbbedabca44b3f1eb7670bc92f49d8401c7374e8'
  18             'SKIP')
  19 validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8')  # Philip Hazel
  20
  21 build() {
  22   cd $pkgname-$pkgver
  23   ./configure \
  24     --prefix=/usr \
  25     --enable-pcre2-16 \
  26     --enable-pcre2-32 \
  27     --enable-jit \
  28     --enable-pcre2grep-libz \
  29     --enable-pcre2grep-libbz2 \
  30     --enable-pcre2test-libreadline
  31   make
  32 }
  33
  34 check() {
  35   cd $pkgname-$pkgver
  36   make -j1 check
  37 }
  38
  39 package() {
  40   cd $pkgname-$pkgver
  41   make DESTDIR="$pkgdir" install
  42
  43   install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  44 }
  45
  46 # vim:set ts=2 sw=2 et: