pyqt6/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 pkgbase=pyqt6
   4 pkgname=python-pyqt6
   5 pkgdesc='A set of Python bindings for the Qt6 toolkit'
   6 pkgver=6.3.1
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://riverbankcomputing.com/software/pyqt/intro'
  10 license=(GPL)
  11 groups=(pyqt6)
  12 depends=(qt6-base python-pyqt6-sip)
  13 optdepends=('qt6-tools: QtHelp, QtDesigner bindings'
  14             'qt6-svg: QtSvg bindings'
  15             'qt6-declarative: QtQml bindings, qmlplugin'
  16             'qt6-quick3d: QtQuick3D bindings'
  17             'qt6-connectivity: QtBluetooth, QtNfc bindings'
  18             'qt6-multimedia: QtMultimedia bindings'
  19             'qt6-positioning: QtPositioning bindings'
  20             'qt6-remoteobjects: QtRemoteObjects bindings'
  21             'qt6-sensors: QtSensors bindings'
  22             'qt6-serialport: QtSerialPort bindings'
  23             'qt6-webchannel: QtWebChannel bindings'
  24             'qt6-websockets: QtWebSockets bindings'
  25             'dbus-python: for python-dbus mainloop support')
  26 makedepends=(sip pyqt-builder python-opengl dbus-python
  27              qt6-tools qt6-svg qt6-declarative qt6-quick3d qt6-shadertools qt6-multimedia qt6-remoteobjects
  28              qt6-positioning qt6-sensors qt6-serialport qt6-webchannel qt6-websockets qt6-connectivity)
  29 source=(https://pypi.python.org/packages/source/P/PyQt6/PyQt6-$pkgver.tar.gz)
  30 sha256sums=('8cc6e21dbaf7047d1fc897e396ccd9710a12f2ef976563dad65f06017d2c9757')
  31 options=(debug)
  32
  33 build() {
  34   cd PyQt6-$pkgver
  35   sip-build \
  36     --confirm-license \
  37     --no-make \
  38     --qmake=/usr/bin/qmake6
  39   cd build
  40   make
  41 }
  42
  43 package_python-pyqt6(){
  44   cd PyQt6-$pkgver/build
  45   make INSTALL_ROOT="$pkgdir" install
  46
  47   # compile Python bytecode
  48   python -m compileall -d / "$pkgdir"/usr/lib
  49   python -O -m compileall -d / "$pkgdir"/usr/lib
  50 }