rtkit/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   3
   4 pkgname=rtkit
   5 pkgver=0.13
   6 pkgrel=2
   7 pkgdesc="Realtime Policy and Watchdog Daemon"
   8 url="https://github.com/heftig/rtkit"
   9 arch=(x86_64)
  10 license=(GPL3 custom:BSD)
  11 depends=(dbus polkit systemd)
  12 makedepends=(git meson vim)
  13 options=(debug)
  14 _commit=b9169402fe5e82d20efb754509eb0b191f214599  # tags/v0.13^0
  15 source=("git+https://github.com/heftig/rtkit?signed#commit=$_commit")
  16 sha256sums=('SKIP')
  17 validpgpkeys=('8218F88849AAC522E94CF470A5E9288C4FA415FA')  # Jan Alexander Steffens (heftig)
  18
  19 pkgver() {
  20   cd rtkit
  21   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd rtkit
  26 }
  27
  28 build() {
  29   arch-meson rtkit build -D installed_tests=false
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38
  39   echo 'u rtkit 133 "RealtimeKit" /proc' |
  40     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/rtkit.conf"
  41
  42   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 rtkit/LICENSE
  43   sed -ne '4,25p' rtkit/rtkit.c |
  44     install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  45 }