sharutils/trunk/PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: Kevin Piche <kevin@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgname=sharutils
   6 pkgver=4.15.2
   7 pkgrel=4
   8 pkgdesc='Makes so-called shell archives out of many files'
   9 url='https://www.gnu.org/software/sharutils/'
  10 license=('GPL')
  11 arch=('x86_64')
  12 depends=('perl' 'gettext' 'texinfo')
  13 validpgpkeys=('1F967B15DEB2349CACDF3D71D9204CB5BFBF0221')
  14 source=("https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig})
  15 sha256sums=('2b05cff7de5d7b646dc1669bc36c35fdac02ac6ae4b6c19cb3340d87ec553a9a'
  16             'SKIP')
  17
  18 prepare() {
  19         cd "${srcdir}/${pkgname}-${pkgver}"
  20         sed 's/FUNC_FFLUSH_STDIN/-1/g' -i lib/fseeko.c
  21 }
  22
  23 build() {
  24         cd "${srcdir}/${pkgname}-${pkgver}"
  25         CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  26         ./configure \
  27                 --prefix=/usr \
  28                 --mandir=/usr/share/man \
  29                 --infodir=/usr/share/info \
  30
  31         make
  32 }
  33
  34 package() {
  35         cd "${srcdir}/${pkgname}-${pkgver}"
  36         make DESTDIR="${pkgdir}" install
  37 }