gobject-introspection/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=gobject-introspection
   5 pkgname=(gobject-introspection gobject-introspection-runtime)
   6 pkgver=1.70.0
   7 pkgrel=4
   8 pkgdesc="Introspection system for GObject-based libraries"
   9 url="https://wiki.gnome.org/Projects/GObjectIntrospection"
  10 arch=(x86_64)
  11 license=(LGPL GPL)
  12 depends=(python-mako python-markdown)
  13 _glibver=2.70.1
  14 makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
  15 options=(!emptydirs)
  16 _commit=4502dd33da995e5e9e6d73aa996cf42e92c9e217  # tags/1.70.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
  18         "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
  19 sha512sums=('SKIP'
  20             'SKIP')
  21 validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip@tecnocode.co.uk>
  22
  23 pkgver() {
  24   cd $pkgbase
  25   git describe --tags | sed 's/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgbase
  30 }
  31
  32 build() {
  33   arch-meson $pkgbase build \
  34     -D gtk_doc=true \
  35     -D glib_src_dir="$srcdir/glib"
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build
  41 }
  42
  43 package_gobject-introspection() {
  44   depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
  45
  46   meson install -C build --destdir "$pkgdir"
  47
  48   python -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
  49   python -O -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
  50
  51 ### Split runtime
  52   mkdir -p "$srcdir/runtime/lib"
  53   mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
  54 }
  55
  56 package_gobject-introspection-runtime() {
  57   pkgdesc+=" (runtime library)"
  58   depends=(glib2)
  59   provides+=(libgirepository-1.0.so)
  60
  61   mv "$srcdir/runtime" "$pkgdir/usr"
  62 }