libomxil-bellagio/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2 # Contributor: Fly-away <flyaaway@gmail.com>
   3
   4 pkgname=libomxil-bellagio
   5 pkgver=0.9.3
   6 pkgrel=3
   7 pkgdesc="An opensource implementation of the OpenMAX Integration Layer API"
   8 arch=('x86_64')
   9 url="http://omxil.sourceforge.net"
  10 license=('LGPL')
  11 depends=('glibc')
  12 source=("https://downloads.sourceforge.net/project/omxil/omxil/Bellagio%200.9.3/${pkgname}-${pkgver}.tar.gz"
  13         fedora-fixes.patch)
  14 md5sums=('a1de827fdb75c02c84e55f740ca27cb8'
  15          'c34f9facf0cf26171c81f2fc3d562ec6')
  16
  17 prepare() {
  18   cd ${pkgname}-$pkgver
  19
  20   # Fixes from fedora repo
  21   patch -Np1 -i ../fedora-fixes.patch
  22   sed -e 's/-Werror//' -i configure.ac
  23   autoreconf -fiv
  24 }
  25
  26 build() {
  27   cd ${pkgname}-${pkgver}
  28
  29   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  30
  31   ./configure --prefix=/usr --disable-static --docdir=/usr/share/doc/${pkgname}
  32   make
  33 }
  34
  35 package() {
  36   cd ${pkgname}-${pkgver}
  37
  38   make DESTDIR="${pkgdir}" install
  39 }