mlt/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Fabian Schoelzel <myfirstname.mylastname@googlemail.com>
   4 # Contributor: funkyou <spamopfer@nickname.berlin.de>
   5 # Contributor: tardo <tardo@nagi-fanboi.net>
   6 # Contributor: Stefan Husmann <stefan-husmann@t-online.de>
   7 # Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
   8
   9 pkgname=mlt
  10 pkgver=7.2.0
  11 pkgrel=3
  12 pkgdesc='An open source multimedia framework'
  13 arch=(x86_64)
  14 url='https://www.mltframework.org'
  15 license=(GPL)
  16 depends=(libebur128)
  17 optdepends=('sdl_image: SDL1 plugin'
  18             'sdl2: SDL2 plugin'
  19             'libsamplerate: libavresample plugin'
  20             'sox: SOX (Audio Swiss Army Knife) plugin'
  21             'ffmpeg: ffmpeg plugin'
  22             'vid.stab: video stabilize plugin'
  23             'qt5-svg: Qt5 plugins'
  24             'jack: JACK sound output plugin'
  25             'ladspa: LADSPA plugins'
  26             'libexif: auto rotate plugin'
  27             'frei0r-plugins: for additional effects'
  28             'movit: opengl plugin'
  29             'opencv: openCV plugin'
  30             'rubberband: audio pitch plugin'
  31             'gdk-pixbuf2: gdk plugin'
  32             'pango: gdk plugin'
  33             'rtaudio: rtaudio plugin'
  34             'python: python bindings')
  35 makedepends=(cmake ladspa frei0r-plugins libdv sdl_image libsamplerate sox ffmpeg vid.stab qt5-svg
  36              jack libexif python swig movit eigen opencv rubberband gdk-pixbuf2 pango rtaudio imagemagick)
  37 source=(https://github.com/mltframework/mlt/archive/v$pkgver/$pkgname-$pkgver.tar.gz
  38         https://github.com/mltframework/mlt/commit/17e34fd3.patch)
  39 sha256sums=('34b737fae61dabddf3ec64477298decb9b2076388ccbda7e50114996b268086d'
  40             'b9392939c907251d2039fdb66450e29fbfb38c77b3626c618e94fea34c21a711')
  41
  42 prepare() {
  43   patch -d $pkgname-$pkgver -p1 < 17e34fd3.patch # Fix sdl module underlinking
  44 }
  45
  46 build() {
  47   cmake -B build -S $pkgname-$pkgver \
  48     -DCMAKE_INSTALL_PREFIX=/usr \
  49     -DMOD_OPENCV=ON \
  50     -DSWIG_PYTHON=ON
  51   cmake --build build
  52 }
  53
  54 package() {
  55   DESTDIR="$pkgdir" cmake --install build
  56 }